Begin Code
' =======================================================================================
' Author: Scott Moss
' Date May 15, 2007
' mom script that will collect daily stats for mom and put them in a
' jet db to run your own reports against it. Put Script in same folder w/ DB.
' Run as a scheduled task at 11:58 PM every day. .
' Requirements
' Create Scheduled Task to run this vb script every night at 11:58 pm.
' *** the objects in MSFT_TodayStatistics zero out at 11:59:59 pm ***
' Create Access Database   MOMRPT.MDB
' Create Table called    momdata
' Create field names that correspond with the recordset objects below
' Date, ComputerGroups, Monitored, CriticalErrors, etc.
' Must give credit to Don Hite. It was his vb script to dump this info into an excel
' file that gave me the idea to do this. Change MOMSERVERNAME to the name of you MOM Server.
' For the Data Source modify as needed to point to the path of your database.
' =======================================================================================
'mom part
' MOM Server Name
strComputer = "MOMSERVERNAME"
 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\MOM")
Set colItems = objWMIService.ExecQuery("Select * from MSFT_TodayStatistics")
dtmThisDate = (Now)
 
'database part
 
Const adOpenStatic = 3
Const adLockOptimistic = 3
 
Set objConnection = CreateObject("ADODB.Connection")
Set objRecordSet = CreateObject("ADODB.Recordset")
 
objConnection.Open _
    "Provider = Microsoft.Jet.OLEDB.4.0; " & _
        "Data Source = momrpt.mdb"
' "Data Source = C:\TEMP\MOMRPT.MDB"
 
objRecordSet.Open "SELECT * FROM momdata" , _
    objConnection, adOpenStatic, adLockOptimistic
 
For Each objItem In colItems
objRecordSet.AddNew
objRecordSet("Date") = dtmThisDate
objRecordSet("ComputerGroups") = objItem.TotalComputerGroups
objRecordSet("Monitored") = objItem.TotalComputersMonitored
objRecordSet("CriticalErrors") = objItem.TotalCriticalErrors
objRecordSet("TotalErrors") = objItem.TotalErrors
objRecordSet("EventsToday") = objItem.TotalEventsToday
objRecordSet("NewAlertsToday") = objItem.TotalNewAlertsToday
objRecordSet("SecurityBreaches") = objItem.TotalSecurityBreaches
objRecordSet("ServiceLevelExceptions") = objItem.TotalServiceLevelExceptions
objRecordSet("ServicesUnavailable") = objItem.TotalServicesUnavailable
objRecordSet("UnresolvedAlerts") = objItem.TotalUnresolvedAlerts
objRecordSet("TotalWarnings") = objItem.TotalWarnings
objRecordSet.Update
 
objRecordSet.Close
objConnection.Close
Next
' END Code